Interlock coordinates AI agents that change production.

# the agent asks first
POST /api/request
{
  "agent":  "deployer-03",
  "action": "deploy",
  "target": "payments@prod",
  "reason": "v2.4 rollout"
}

# the answer says what to do and why
{
  "status": "waiting",
  "reason": "Waits for migrator-11 (migrate orders-db).
             Both changes reach checkout:
             orders-db → orders → checkout,
             and payments → checkout."
}

// everything that depends on the target, up to 2 hops away
MATCH (t:Resource {id: $target})
OPTIONAL MATCH p = (d:Resource)-[:DEPENDS_ON*1..2]->(t)
WITH t, d, min(length(p)) AS hops
RETURN t.id AS target,
       collect({id: d.id, hops: hops, tier: d.tier}) AS zone

// deploy and migrate: 2 hops. restart: 1. delete: 3.
// the zone is stored as IMPACTS edges on the Intent node.

// check and grant in one write: two agents cannot both win
MATCH (n:Intent {id: $id})
OPTIONAL MATCH (n)-[a:IMPACTS]->(r:Resource)<-[b:IMPACTS]-(g:Intent {status: 'granted'})
WHERE g <> n AND (
      (a.role = 'target' AND n.mode = 'exclusive')
   OR (b.role = 'target' AND g.mode = 'exclusive')
   OR (r.tier = 1 AND n.mode = 'exclusive' AND g.mode = 'exclusive'))
WITH n, collect(DISTINCT g) AS blockers
SET n.status = CASE WHEN size(blockers) = 0 THEN 'granted' ELSE 'waiting' END
FOREACH (g IN blockers | MERGE (n)-[:WAITS_FOR]->(g))

// is a human behind this agent, through any sub-agents?
MATCH (a:Agent {id: $agent}), (r:Resource {id: $target})-[:OWNED_BY]->(team:Team)
OPTIONAL MATCH (h:Human)-[:AUTHORIZED]->(top:Agent)-[d:DELEGATED_TO*0..3]->(a)
WHERE (h)-[:CAN_CHANGE]->(team)
RETURN h.name, [x IN nodes(d) | x.name] AS chain

// agents that wait on each other in a circle
MATCH p = (a:Agent)-[:WAITS_ON*2..8]->(a)
RETURN [x IN nodes(p) | x.id] AS cycle LIMIT 1

// the record, written before the action runs
MATCH (n:Intent {id: $iid})
CREATE (:Decision {verdict: $verdict, reason: $reason, path: $path, chain: $chain})-[:ABOUT]->(n)